mirror of
https://chromium.googlesource.com/libyuv/libyuv
synced 2025-12-07 01:06:46 +08:00
db694edfc2
BUG=126 TEST=convert tests NV12 with alignments Review URL: https://webrtc-codereview.appspot.com/896007 git-svn-id: http://libyuv.googlecode.com/svn/trunk@426 16f28f9a-4ce2-e073-06de-1de4eb20be90
106 lines
2.7 KiB
NASM
106 lines
2.7 KiB
NASM
;
|
|
; Copyright 2012 The LibYuv Project Authors. All rights reserved.
|
|
;
|
|
; Use of this source code is governed by a BSD-style license
|
|
; that can be found in the LICENSE file in the root of the source
|
|
; tree. An additional intellectual property rights grant can be found
|
|
; in the file PATENTS. All contributing project authors may
|
|
; be found in the AUTHORS file in the root of the source tree.
|
|
;
|
|
|
|
%ifdef __YASM_VERSION_ID__
|
|
%if __YASM_VERSION_ID__ < 01020000h
|
|
%error AVX2 is supported only by yasm 1.2.0 or later.
|
|
%endif
|
|
%endif
|
|
%include "x86inc.asm"
|
|
|
|
SECTION .text
|
|
|
|
; void YUY2ToYRow_SSE2(const uint8* src_yuy2, uint8* dst_y, int pix);
|
|
|
|
%macro YUY2TOYROW 2-3
|
|
cglobal %1ToYRow%3, 3, 3, 3, src_yuy2, dst_y, pix
|
|
%ifidn %1,YUY2
|
|
pcmpeqb m2, m2, m2 ; generate mask 0x00ff00ff
|
|
psrlw m2, m2, 8
|
|
%endif
|
|
|
|
ALIGN 16
|
|
.convertloop:
|
|
mov%2 m0, [src_yuy2q]
|
|
mov%2 m1, [src_yuy2q + mmsize]
|
|
lea src_yuy2q, [src_yuy2q + mmsize * 2]
|
|
%ifidn %1,YUY2
|
|
pand m0, m0, m2 ; YUY2 even bytes are Y
|
|
pand m1, m1, m2
|
|
%else
|
|
psrlw m0, m0, 8 ; UYVY odd bytes are Y
|
|
psrlw m1, m1, 8
|
|
%endif
|
|
packuswb m0, m0, m1
|
|
sub pixd, mmsize
|
|
mov%2 [dst_yq], m0
|
|
lea dst_yq, [dst_yq + mmsize]
|
|
jg .convertloop
|
|
REP_RET
|
|
%endmacro
|
|
|
|
; TODO(fbarchard): Remove MMX. Add SSSE3 pshufb version.
|
|
INIT_MMX MMX
|
|
YUY2TOYROW YUY2,a,
|
|
YUY2TOYROW YUY2,u,_Unaligned
|
|
YUY2TOYROW UYVY,a,
|
|
YUY2TOYROW UYVY,u,_Unaligned
|
|
INIT_XMM SSE2
|
|
YUY2TOYROW YUY2,a,
|
|
YUY2TOYROW YUY2,u,_Unaligned
|
|
YUY2TOYROW UYVY,a,
|
|
YUY2TOYROW UYVY,u,_Unaligned
|
|
INIT_YMM AVX2
|
|
YUY2TOYROW YUY2,a,
|
|
YUY2TOYROW YUY2,u,_Unaligned
|
|
YUY2TOYROW UYVY,a,
|
|
YUY2TOYROW UYVY,u,_Unaligned
|
|
|
|
; void SplitUV_Unaligned_SSE2(const uint8* src_uv, uint8* dst_u, uint8* dst_v,
|
|
; int pix) {
|
|
|
|
%macro SPLITUV 1-2
|
|
cglobal SplitUV%2, 4, 4, 5, src_uv, dst_u, dst_v, pix
|
|
pcmpeqb m4, m4, m4 ; generate mask 0x00ff00ff
|
|
psrlw m4, m4, 8
|
|
sub dst_vq, dst_uq
|
|
|
|
ALIGN 16
|
|
.convertloop:
|
|
mov%1 m0, [src_uvq]
|
|
mov%1 m1, [src_uvq + mmsize]
|
|
lea src_uvq, [src_uvq + mmsize * 2]
|
|
mova m2, m0
|
|
mova m3, m1
|
|
pand m0, m0, m4 ; even bytes
|
|
pand m1, m1, m4
|
|
packuswb m0, m0, m1
|
|
psrlw m2, m2, 8 ; odd bytes
|
|
psrlw m3, m3, 8
|
|
packuswb m2, m2, m3
|
|
mov%1 [dst_uq], m0
|
|
mov%1 [dst_uq + dst_vq], m2
|
|
lea dst_uq, [dst_uq + mmsize]
|
|
sub pixd, mmsize
|
|
jg .convertloop
|
|
REP_RET
|
|
%endmacro
|
|
|
|
INIT_MMX MMX
|
|
SPLITUV a,
|
|
SPLITUV u,_Unaligned
|
|
INIT_XMM SSE2
|
|
SPLITUV a,
|
|
SPLITUV u,_Unaligned
|
|
INIT_YMM AVX2
|
|
SPLITUV a,
|
|
SPLITUV u,_Unaligned
|
|
|